Java-Syntax -- kompakt

Zeichen ::=

\ u { u } Hexadezimalziffer Hexadezimalziffer Hexadezimalziffer Hexadezimalziffer |
Unicode-Zeichen .

Eingabezeichen ::=

< Zeichen, aber nicht ASCII-CR,ASCII-LF > .

Zeilenendekennzeichen ::=

ASCII-CR ASCII-LF | ASCII-CR | ASCII-LF .

Quelltext ::=

{ Kommentar | Leerzeichen | Sprachelement } .

Leerzeichen ::=

ASCII-SP | ASCII-HT | ASCII-FF | Zeilenendekennzeichen .

Sprachelement ::=

Schlüsselwort | Identifikator | Literal | Separator
| Operator .

Operator ::=

Inkrementoperator | Dekrementoperator | Vorzeichenoperator
| Negationsoperator | Multiplikationsoperator | Additionsoperator
| Schiebeoperator | Ordnungsoperator | Vergleichsoperator
| ? | : | && | || | & | | | ^ | Zuweisungsoperator .

Kommentar ::=

/* < Zeichen, aber nicht * > { Kommentarinhalt } */ |
/** { Kommentarinhalt } */ |
// Kommentarzeile Zeilenendekennzeichen .

Kommentarinhalt ::=

{
< Zeichen, aber nicht * > Zeichen |
* < Zeichen, aber nicht / > Zeichen |
Zeilenendekennzeichen
} .

Kommentarzeile ::=

{ Zeichen } .

Identifikator ::=

Unicode-Buchstabe
{ Unicode-Buchstabe | Unicode-Ziffer } .

Literal ::=

Zahl-Literal | Gleitkommazahl-Literal |
Wahrheitswert-Literal |
Zeichen-Literal | Zeichenkette-Literal |
Klassen-Literal .

Zahl-Literal ::=

(
Dezimalzahl-Literal | Oktalzahl-Literal |
Hexadezimalzahl-Literal
)
[ l | L ] .

Dezimalzahl-Literal ::=

< Ziffer, aber nicht 0 > { Ziffer } .

Oktalziffer ::=

0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 .

Ziffer ::=

Oktalziffer | 8 | 9 .

Hexadezimalziffer ::=

Ziffer | a | A | b | B |
c | C | d | D | e | E | f | F .

Hexadezimalzahl-Literal ::=

0 ( x | X ) { Hexadezimalziffer } .

Oktalzahl-Literal ::=

0 { Oktalziffer } .

Gleitkommazahl-Literal ::=

(
Ziffer { Ziffer } . { Ziffer } [ Exponent ] |
. Ziffer { Ziffer } [ Exponent ] |
Ziffer { Ziffer } Exponent
)
[ f | F | d | D ] .

Exponent ::=

( e | E ) [ [ + | - ] Ziffer { Ziffer } ] .

Wahrheitswert-Literal ::=

true | false .

Zeichen-Literal ::=

' ( < Zeichen, aber nicht ' oder \ > | Escape-Literal ) ' .

Escape-Literal ::=

\b | \t | \n | \f | \r | \" | \' | \\ |
Oktalziffer | Oktalziffer Oktalziffer |
( 0 | 1 | 2 | 3 ) Oktalziffer Oktalziffer .

Zeichenkette-Literal ::=

" { < Zeichen, aber nicht " oder \ > | Escape-Literal } " .

Klassen-Literal ::=

Typ .class .

Schlüsselwort ::=

abstract | boolean | break | byte | case | cast | catch | char | class | const | continue | default | do | double | else | extends | final | finally | float | for | future | generic | goto | if | implements | import | inner | instanceof | int | interface | long | native | new | null | operator | outer | package | private | protected | public | rest | return | short | static | super | switch | synchronized | this | throw | throws | transient | try | var | void | while .

Separator ::=

( | ) | { | } | [ | ] | ; | , | . .

Quelltextdatei ::=

[ Paketfestlegung ] { Import } { Typdeklaration } .

Paketfestlegung ::=

package Paketname ; .

Paketname ::=

Bezeichner .

Import ::=

Typimport | Paket-Typimport .

Typimport ::=

import Paketname . Identifikator ; .

Paket-Typimport ::=

import Paketname .* ; .

Typdeklaration ::=

Klassendeklaration | Schnittstellendeklaration .

Toplevelklasse ::=

[ Klassensichtbarkeit ] Klassendeklaration .

Klassendeklaration ::=

[ Abstraktionsebene ] class Identifikator
[ extends Klassentyp ]
[ implements Schnittstellentyp { , Schnittstellentyp } ]
Klassenkörper .

Klassensichtbarkeit ::=

public .

Abstraktionsebene ::=

abstract | final .

Klassenkörper ::=

{ { Komponentendeklaration | Initialisierung } } .

Komponentendeklaration ::=

Variablendeklaration | Methodendeklaration |
Konstruktordeklaration | InnereKlasse .

InnereKlasse ::=

[ Sichtbarkeit ] [ static ] Klassendeklaration |
[ Sichtbarkeit ] [ static ] Schnittstellendeklaration .

Variablendeklaration ::=

[ Sichtbarkeit ]
( [ static ] [ final ] | [ transient ] )
Typ Variable { , Variable } ; .

Sichtbarkeit ::=

public | protected | private .

Variable ::=

Identifikator { [] } [ = Variableninitialisierung ] .

Variableninitialisierung ::=

Ausdruck |
[ new Feldtyp ] { [ Variableninitialisierung { , Variableninitialisierung } ] } .

Methodendeklaration ::=

[ Sichtbarkeit ] [ static ] [ Abstraktionsebene ]
[ Quelle ] [ Synchronisation ]
Methodensignatur [ throws Referenztyp { , Referenztyp } ] Methodenkörper .

Synchronisation ::=

synchronized .

Quelle ::=

native .

Resultattyp ::=

void | Typ .

Methodensignatur ::=

Resultattyp Identifikator { [] } ( [ Parameterliste ] ) { [] } .

Parameterliste ::=

[ final ] Typ Identifikator { [] }
{ , [ final ] Typ Identifikator { [] } } .

Methodenkörper ::=

Block | ; .

Konstruktordeklaration ::=

[ Sichtbarkeit ] Klassentyp ( [ Parameterliste ] )
[ throws Referenztyp { , Referenztyp } ] Konstruktorkörper .

Konstruktorkörper ::=

{ [ Konstruktoraufruf ] [ Blockkörper ] } .

Konstruktoraufruf ::=

( this | [ Referenzausdruck . ] super ) ( Argumentliste ) ; .

Initialisierung ::=

[ static ] Block .

Schnittstellendeklaration ::=

[ Schnittstellensichtbarkeit ]
[ Schnittstellenbenutzung ] interface Identifikator
[ extends Schnittstellentyp { , Schnittstellentyp } ] Schnittstellenkörper .

Schnittstellensichtbarkeit ::=

public .

Schnittstellenbenutzung ::=

abstract .

Schnittstellenkörper ::=

{ { Schnittstellenkomponentendeklaration } } .

Schnittstellenkomponentendeklaration ::=

Schnittstellenvariablendeklaration | Schnittstellenmethodendeklaration |
InnereKlasse .

Schnittstellenvariablendeklaration ::=

[ Schnittstellensichtbarkeit ]
[ static ] [ final ]
Typ Schnittstellenvariable { , Schnittstellenvariable } ; .

Schnittstellenvariable ::=

Identifikator { [] } = Schnittstellenvariableninitialisierung .

Schnittstellenvariableninitialisierung ::=

Konstantenausdruck |
{ [ Schnittstellenvariableninitialisierung
{ , Schnittstellenvariableninitialisierung } ] } .

Schnittstellenmethodendeklaration ::=

[ Schnittstellensichtbarkeit ] [ Schnittstellenbenutzung ]
Methodensignatur [ throws Referenztyp { , Referenztyp } ] ; .

Typ ::=

Referenztyp | Standardtyp .

Referenztyp ::=

Klassentyp | Schnittstellentyp | Feldtyp .

Standardtyp ::=

boolean | char | byte | short | int | long | float | double .

Klassentyp ::=

Bezeichner .

Schnittstellentyp ::=

Bezeichner .

Feldtyp ::=

Typ [] .

Block ::=

{ Blockkörper } .

Blockkörper ::=

{ Lokalvariablendeklaration ; | Anweisung
| Klassendeklaration } .

Lokalvariablendeklaration ::=

[ final ] Typ Variable { , Variable } .

Anweisung ::=

Leeranweisung | Ausdrucksberechnung ; |
Auswahlanweisung | Schleifenanweisung | Sprungmarkierung |
Sprunganweisung ; |
Synchronisationsanweisung | Ausnahmeanweisung | Block .

Leeranweisung ::=

; .

Ausdrucksberechnung ::=

Zuweisung | Präinkrement | Postinkrement |
Prädekrement | Postdekrement | Methodenaufruf | Objekterzeugung .

Zuweisung ::=

Referenzzugriff Zuweisungsoperator Ausdruck .

Zuweisungsoperator ::=

= | += | *= | -= | /= | %= | &= | |= | ^=
| <<= | >>= | >>= .

Präinkrement ::=

Inkrementoperator Referenzzugriff .

Postinkrement ::=

Referenzzugriff Inkrementoperator .

Prädekrement ::=

Dekrementoperator Referenzzugriff .

Postdekrement ::=

Referenzzugriff Dekrementoperator .

Inkrementoperator ::=

++ .

Dekrementoperator ::=

-- .

Methodenaufruf ::=

Komponentenzugriff ( [ Argumentliste ] ) .

Auswahlanweisung ::=

if ( Ausdruck ) Anweisung [ else Anweisung ] |
switch ( Ausdruck ) { { Fallunterscheidung } } .

Fallunterscheidung ::=

case Konstantenausdruck : Anweisung |
default : Anweisung .

Schleifenanweisung ::=

while ( [ Ausdruck ] ) Anweisung |
do Anweisung while ( [ Ausdruck ] ) ; |
for ( Schleifeninitialisierung ; [ Ausdruck ] ; Schleifenschritt ) Anweisung .

Schleifeninitialisierung ::=

Schleifenschritt | Lokalvariablendeklaration .

Schleifenschritt ::=

[ Ausdrucksberechnung { , Ausdrucksberechnung } ] .

Sprungmarkierung ::=

Identifikator : Schleifenanweisung .

Sprunganweisung ::=

break [ Identifikator ] |
continue [ Identifikator ] |
return [ Ausdruck ] |
throw Referenzzugriff .

Synchronisationsanweisung ::=

synchronized ( Ausdruck ) Anweisung .

Ausnahmeanweisung ::=

try Block { catch ( Ausnahme Identifikator ) Block }
( finally | catch ( Ausnahme Identifikator ) ) Block .

Ausnahme ::=

Klassentyp .

Argumentliste ::=

Ausdruck { , Ausdruck } .

Referenzausdruck ::=

Referenzzugriff | Objekterzeugung .

Grundausdruck ::=

Referenzausdruck | Literal .

Referenzzugriff ::=

Bezeichner | Feldzugriff | Komponentenzugriff |
Methodenaufruf | ( Ausdruck ) .

Bezeichner ::=

[ Qualifikator . ] Identifikator | this | super | null .

Qualifikator ::=

{ Identifikator . } Identifikator .

Feldzugriff ::=

Referenzausdruck [ Ausdruck ] .

Komponentenzugriff ::=

[ ( Referenzausdruck | Zeichenkette-Literal ) . ] Identifikator .

Objekterzeugung ::=

[ Referenzausdruck . ] new Typ
(
( [ Argumentliste ] ) [ Klassenkörper ] |
[ Ausdruck ] { [ Ausdruck ] } { [ ] }
) .

Faktor ::=

Präinkrement | Prädekrement | Grundfaktor |
Vorzeichenoperator Faktor .

Vorzeichenoperator ::=

+ | - .

Grundfaktor ::=

Grundausdruck | Postinkrement | Postdekrement |
Typkonvertierung | Negationsoperator Faktor .

Negationsoperator ::=

~ | ! .

Typkonvertierung ::=

( Standardtyp ) Faktor | ( Typ ) Grundfaktor .

Term ::=

Faktor { Multiplikationsoperator Faktor } .

Multiplikationsoperator ::=

* | / | % .

Additionsausdruck ::=

Term { Additionsoperator Term } .

Additionsoperator ::=

+ | - .

Schiebeausdruck ::=

Additionsausdruck { Schiebeoperator Additionsausdruck } .

Schiebeoperator ::=

<< | >> | >>> .

Ordnungsausdruck ::=

Schiebeausdruck { Ordnungsoperator Schiebeausdruck } |
Schiebeausdruck instanceof Typ { [ ] } .

Ordnungsoperator ::=

< | > | <= | >= .

Vergleichsausdruck ::=

Ordnungsausdruck { Vergleichsoperator Ordnungsausdruck } .

Vergleichsoperator ::=

== | != .

Bit-Und-Ausdruck ::=

Vergleichsausdruck { & Vergleichsausdruck } .

Bit-Exklusiv-Oder-Ausdruck ::=

Bit-Und-Ausdruck { ^ Bit-Und-Ausdruck } .

Bit-Oder-Ausdruck ::=

Bit-Exklusiv-Oder-Ausdruck { | Bit-Exklusiv-Oder-Ausdruck } .

Und-Ausdruck ::=

Bit-Oder-Ausdruck { && Bit-Oder-Ausdruck } .

Oder-Ausdruck ::=

Und-Ausdruck { || Und-Ausdruck } .

Bedingungsausdruck ::=

Oder-Ausdruck { ? Ausdruck : Oder-Ausdruck } .

Ausdruck ::=

Bedingungsausdruck | Zuweisung .